Function Reference

_WinAPI_EnumWindowsPopup

Enumerates popup windows

#include <WinAPISysWin.au3>
_WinAPI_EnumWindowsPopup ( )

Return Value

Returns an array with the following format:
    [0][0] - Number of rows in array (n)
    [1][0] - Window handle
    [1][1] - Window class name
    [n][0] - Window handle
    [n][1] - Window class name

Related

_WinAPI_EnumWindows, _WinAPI_EnumWindowsTop

Example

#include <Array.au3>
#include <WinAPISysWin.au3>

ToolTip("test Popup") ; to have at least one popup window

Example()

Func Example()
        Local $aWindows = _WinAPI_EnumWindowsPopup()
        Local $aResult[$aWindows[0][0]][5]
        For $i = 1 To $aWindows[0][0]
                $aResult[$i - 1][0] = $aWindows[$i][0]
                $aResult[$i - 1][1] = $aWindows[$i][1]
                $aResult[$i - 1][2] = WinGetTitle($aWindows[$i][0])
                $aResult[$i - 1][3] = WinGetText($aWindows[$i][0])
                $aResult[$i - 1][4] = WinGetProcess($aWindows[$i][0])
        Next
        _ArrayDisplay($aResult, "_WinAPI_EnumWindowsPopup", Default, Default, Default, "#|Handle|Class|Title|Text|Process")
EndFunc   ;==>Example